请选择 进入手机版 | 继续访问电脑版

LibreOffice中文社区

 找回密码
 马上加入

QQ登录

只需一步,快速开始

扫一扫,访问微社区

搜索
开启左侧

[问题] 已经解决.结贴 LibreOffice中如何将数字转换成大写金额?

[复制链接]
evrerve 发表于 2016-2-3 13:13:03 | 显示全部楼层 |阅读模式
本帖最后由 evrerve 于 2016-4-4 11:13 编辑

在excel中,A2是转换前的(阿拉伯数字)金额,如果要严格按照财务对大小写金额转换的要求来说,可以在B2单元格输入公式
=SUBSTITUTE(SUBSTITUTE(TEXT(INT(A2),"[DBNum2][$-804]G/通用格式元"&IF(INT(A2)=A2,"整",""))&TEXT(MID(A2,FIND(".",A2&".0")+1,1),"[DBNum2][$-804]G/通用格式角")&TEXT(MID(A2,FIND(".",A2&".0")+2,1),"[DBNum2][$-804]G/通用格式分"),"零角","零"),"零分","")


那么在LibreOffice中,打开这个文件,提示错误:502;
正确的改法(或公式)是什么呀,请教大神!

jmxhyz 发表于 2016-4-1 17:47:54 | 显示全部楼层
本帖最后由 jmxhyz 于 2016-4-1 18:42 编辑

改为这个样子:
=SUBSTITUTE(SUBSTITUTE(TEXT(INT(A2),"[NatNum5][$-804]0元"&IF(INT(A2)=A2,"整",""))&TEXT(MID(A2,FIND(".",A2&".0")+1,1),"[NatNum5][$-804]0角")&TEXT(MID(A2,FIND(".",A2&".0")+2,1),"[NatNum5][$-804]0分"),"零角","零"),"零分","")

就是把:
[DBNum2][$-804]G/通用格式
改为:
[NatNum5][$-804]0
 楼主| evrerve 发表于 2016-3-31 12:59:55 | 显示全部楼层
提问防沉,见谅。
 楼主| evrerve 发表于 2016-4-1 21:47:56 | 显示全部楼层
jmxhyz 发表于 2016-4-1 17:47
改为这个样子:
=SUBSTITUTE(SUBSTITUTE(TEXT(INT(A2),"[NatNum5][$-804]0元"&IF(INT(A2)=A2,"整",""))&TEX ...

收到;学习了;
grassvalley 发表于 2017-8-21 08:26:52 | 显示全部楼层
"[NatNum5][$-804]0元"  第一次见到这样的字符串,这是什么意思啊?
jmxhyz 发表于 2017-8-24 11:48:08 | 显示全部楼层
grassvalley 发表于 2017-8-21 08:26
"[NatNum5][$-804]0元"  第一次见到这样的字符串,这是什么意思啊?

数字格式码,参考:https://help.libreoffice.org/Common/Number_Format_Codes/zh-CN

NatNum  ==>  native number characters(本地数字格式,根据所选择的国家地区,显示当地的字符格式)
当选择NatNum5时,如果文档设置为中国,则显示中国的数字大写字符,

$-804,同上,表示选择804(中国)的货币表示方式。
jmxhyz 发表于 2017-8-24 12:03:37 | 显示全部楼层
上面的将数字转换成大写金额的公式有错误。会将最后的零分去掉。比如 ¥1.5 ==> 壹元伍角

若保留后面的“零分”,可用下面的公式:
=TEXT(INT(A2),"[NatNum5][$-804]0元") & IF(INT(A2)=A2,"整",(TEXT(INT(A2*10)-INT(A2)*10,"[NatNum5][$-804]0角") & TEXT(INT(A2*100)-INT(A2*10)*10,"[NatNum5][$-804]0分")))

或者省略[$-804]也可以。
=TEXT(INT(A2),"[NatNum5]0元") & IF(INT(A2)=A2,"整",(TEXT(INT(A2*10)-INT(A2)*10,"[NatNum5]0角") & TEXT(INT(A2*100)-INT(A2*10)*10,"[NatNum5]0分")))

需要前面加¥人民币符号的
=TEXT(INT(A2),"[NatNum5][$¥-804]0元") & IF(INT(A2)=A2,"整",(TEXT(INT(A2*10)-INT(A2)*10,"[NatNum5][$-804]0角") & TEXT(INT(A2*100)-INT(A2*10)*10,"[NatNum5][$-804]0分")))
*滑块验证:
您需要登录后才可以回帖 登录 | 马上加入

本版积分规则

小黑屋|手机版|Archiver|LibreOffice中文社区 ( 粤ICP备13080851号-4 )  

GMT+8, 2017-11-20 03:31 , Processed in 0.095455 second(s), 23 queries .

Powered by Discuz! X3.4

© 2001-2017 Comsenz Inc.

快速回复 返回顶部 返回列表